弘毅 发表于 2012-9-18 22:20:28

LaunchPad Energia学习笔记03--用BMP085显示气压与温度


首先看一下硬件连接图:
P1.6引脚接SCL,P1.7接SDA,VCC与GND接入模块上对应的就OK



注意~~~因为P1.6也同时连接着LED2,为了不影响IIC的通信,一定要把LED2的跳线帽拔掉,否则就会工作不正常。



我们把下面的代码放入Energia中进行编译,下载进入Launchpad。

/*
从BMP085传感器读取温度与气压数据。
通过Serial.print命令以9600波特率发送至串口监视器。
*/

#include <Wire.h>
#define BMP085_ADDRESS 0x77// BMP085的I2C地址
const unsigned char OSS = 0;// 采样设置

// 校准值
int ac1;
int ac2;
int ac3;
unsigned int ac4;
unsigned int ac5;
unsigned int ac6;
int b1;
int b2;
int mb;
int mc;
int md;

// b5用于计算bmp085GetTemperature(...),它也同时用于bmp085GetPressure(...)
// 所以Temperature(...)必须在Pressure(...)之前声明

long b5;
short temperature;
long pressure;

void setup()
{
Serial.begin(9600);
Wire.begin();
bmp085Calibration();
}

void loop()
{
temperature = bmp085GetTemperature(bmp085ReadUT());
pressure = bmp085GetPressure(bmp085ReadUP());
Serial.print("Temperature: ");
Serial.print(temperature, DEC);
Serial.println(" *0.1 deg C");
Serial.print("Pressure: ");
Serial.print(pressure, DEC);
Serial.println(" Pa");
Serial.println();
delay(1000);
}

// 存储所有的BMP085的校准值到全局变量
// 校准值用来计算温度与气压
// 这个函数应该放在程序的开头

void bmp085Calibration()
{
ac1 = bmp085ReadInt(0xAA);
ac2 = bmp085ReadInt(0xAC);
ac3 = bmp085ReadInt(0xAE);
ac4 = bmp085ReadInt(0xB0);
ac5 = bmp085ReadInt(0xB2);
ac6 = bmp085ReadInt(0xB4);
b1 = bmp085ReadInt(0xB6);
b2 = bmp085ReadInt(0xB8);
mb = bmp085ReadInt(0xBA);
mc = bmp085ReadInt(0xBC);
md = bmp085ReadInt(0xBE);
}

// 计算温度赋值给变量ut
// 返回值的精度在0.1摄氏度

short bmp085GetTemperature(unsigned int ut)
{
long x1, x2;
x1 = (((long)ut - (long)ac6)*(long)ac5) >> 15;
x2 = ((long)mc << 11)/(x1 + md);
b5 = x1 + x2;
return ((b5 + 8)>>4);
}

// 计算压力
// 校准值必须是已知的
// B5在bmp085GetTemperature(...)需要使用,所以必须先调用。
// 返回值以Pa为单位

long bmp085GetPressure(unsigned long up)

{
long x1, x2, x3, b3, b6, p;
unsigned long b4, b7;
b6 = b5 - 4000;
// 计算B3
x1 = (b2 * (b6 * b6)>>12)>>11;
x2 = (ac2 * b6)>>11;
x3 = x1 + x2;
b3 = (((((long)ac1)*4 + x3)<<OSS) + 2)>>2;
// 计算B4
x1 = (ac3 * b6)>>13;
x2 = (b1 * ((b6 * b6)>>12))>>16;
x3 = ((x1 + x2) + 2)>>2;
b4 = (ac4 * (unsigned long)(x3 + 32768))>>15;
b7 = ((unsigned long)(up - b3) * (50000>>OSS));
if (b7 < 0x80000000)
    p = (b7<<1)/b4;
else
    p = (b7/b4)<<1;
x1 = (p>>8) * (p>>8);
x1 = (x1 * 3038)>>16;
x2 = (-7357 * p)>>16;
p += (x1 + x2 + 3791)>>4;
return p;
}

// 在BMP085的'address'中读取一个字节
char bmp085Read(unsigned char address)
{
unsigned char data;
Wire.beginTransmission(BMP085_ADDRESS);
Wire.write(address);
Wire.endTransmission();
Wire.requestFrom(BMP085_ADDRESS, 1);
while(!Wire.available());
return Wire.read();
}
// 从BMP085读取两个字节
// 第一个字节是从'address'
// 第二个字节是从'address'+1
int bmp085ReadInt(unsigned char address)
{
unsigned char msb, lsb;
Wire.beginTransmission(BMP085_ADDRESS);
Wire.write(address);
Wire.endTransmission();
Wire.requestFrom(BMP085_ADDRESS, 2);
while(Wire.available()<2);
msb = Wire.read();
lsb = Wire.read();
return (int) msb<<8 | lsb;
}

// 读取未补偿的温度值
unsigned int bmp085ReadUT()

{
unsigned int ut;
// 在寄存器0xF4写入0x2E
// 这个用来请求进行温度读取
Wire.beginTransmission(BMP085_ADDRESS);

Wire.write(0xF4);

Wire.write(0x2E);
Wire.endTransmission();
// 至少等待4.5ms
delay(5);
// 从寄存器0xF6与0xF7读取两个字节
ut = bmp085ReadInt(0xF6);
return ut;
}

// 读取未补偿的压力值
unsigned long bmp085ReadUP()
{
unsigned char msb, lsb, xlsb;
unsigned long up = 0;
// 写入0x34+(OSS<<6)到寄存器0xF4
// 请求气压数据读取
Wire.beginTransmission(BMP085_ADDRESS);
Wire.write(0xF4);
Wire.write(0x34 + (OSS<<6));
Wire.endTransmission();
// 等待转换,延迟时间依赖于OSS
delay(2 + (3<<OSS));
// 读取寄存器0xF6 (MSB), 0xF7 (LSB), and 0xF8 (XLSB)
Wire.beginTransmission(BMP085_ADDRESS);
Wire.write(0xF6);
Wire.endTransmission();
Wire.requestFrom(BMP085_ADDRESS, 3);
// 等待数据变为可用
while(Wire.available() < 3);
msb = Wire.read();
lsb = Wire.read();
xlsb = Wire.read();
up = (((unsigned long) msb << 16) | ((unsigned long) lsb << 8) | (unsigned long) xlsb) >> (8-OSS);
return up;
}


下载程序的模式,TX RX的跳线帽一定要纵向链接。如图:



当下载好以后,我们需要把两个跳线帽拔下来,横向连接,这样子才能把数据通过串口发回电脑上,如图:



然后启动Energia的串口监视器,我们就能看到BMP085气压传感器返回的数据了。

Randy 发表于 2012-9-18 22:54:38

这个和arduino的库一样的吧?

弘毅 发表于 2012-9-18 22:58:57

Randy 发表于 2012-9-18 22:54 static/image/common/back.gif
这个和arduino的库一样的吧?

嗯。。。。一样。。代码都通用。。。

幻生幻灭 发表于 2012-9-19 09:56:22

fritzing 中的两处跳帽未处理,容易误导新手的说哦

水乐天 发表于 2012-9-19 11:03:31

教程写得不错 哈哈

┏ωǒ┛菰独 发表于 2012-9-19 16:55:38

我串口通信的时候跳线帽是不需要改动的啊

弘毅你的launchpad 是什么版本的??

我的盒子上 rev 是 0033317

弘毅 发表于 2012-9-19 17:17:54

┏ωǒ┛菰独 发表于 2012-9-19 16:55 static/image/common/back.gif
我串口通信的时候跳线帽是不需要改动的啊

弘毅你的launchpad 是什么版本的??


我的板子上是REV.1.5~~~盒子上。。得明天去翻翻

┏ωǒ┛菰独 发表于 2012-9-19 17:32:25

弘毅 发表于 2012-9-19 17:17 static/image/common/back.gif
我的板子上是REV.1.5~~~盒子上。。得明天去翻翻

我的也是rev1.5不用翻了...好奇怪..不改跳线帽确实用不起来吗?
还有 ,我用iar烧程序的时候不需要txd和rxd,我这两个跳线帽通常也是移除掉的,因为串口电平会干扰.
430用在arduino下是不是用了bootloader?

弘毅 发表于 2012-9-19 17:57:18

┏ωǒ┛菰独 发表于 2012-9-19 17:32 static/image/common/back.gif
我的也是rev1.5不用翻了...好奇怪..不改跳线帽确实用不起来吗?
还有 ,我用iar烧程序的时候不需要txd ...

没用bootloader~~~用Energia往串口监视器发送数据。。就需要改跳线帽,很麻烦。。。不知道怎么能。。不改跳线帽就能用。

水乐天 发表于 2012-9-20 16:38:42

=.= 我一直横向就可以啊。

弘毅 发表于 2012-9-20 17:15:42

水乐天 发表于 2012-9-20 16:38 static/image/common/back.gif
=.= 我一直横向就可以啊。

啊。。。。横向也能下载程序。我还没试。。。赶紧试试

AndersonBY 发表于 2012-9-21 11:04:04

┏ωǒ┛菰独 发表于 2012-9-19 17:32 static/image/common/back.gif
我的也是rev1.5不用翻了...好奇怪..不改跳线帽确实用不起来吗?
还有 ,我用iar烧程序的时候不需要txd ...

根据TI说明横向连接表示使用硬件串口通信,就是G2553上的硬件串口,如果纵向连接就是使用软件模拟的方式实现串口通信的。

┏ωǒ┛菰独 发表于 2012-9-21 12:25:21

AndersonBY 发表于 2012-9-21 11:04 static/image/common/back.gif
根据TI说明横向连接表示使用硬件串口通信,就是G2553上的硬件串口,如果纵向连接就是使用软件模拟的方式实 ...

你这句话突然点明白了 为什么我前些日子把launchpad用作usb转ttl,给msp430f5438板子用的时候,为什么电平有问题...原来我忽略了它电路设计的一个部分.

zintiger 发表于 2013-2-22 09:49:19

谢谢,学习了。问个问题:如果另外再连一个I2C设备,如MPU6050,它也要用到SDA和SCL,它们会发生冲突吗?软件上如何处理?

弘毅 发表于 2013-2-22 09:50:42

zintiger 发表于 2013-2-22 09:49 static/image/common/back.gif
谢谢,学习了。问个问题:如果另外再连一个I2C设备,如MPU6050,它也要用到SDA和SCL,它们会发生冲突吗?软 ...

只要I2C的地址不一样就不会冲突
页: [1] 2
查看完整版本: LaunchPad Energia学习笔记03--用BMP085显示气压与温度