shihaipeng04 发表于 2014-5-15 00:28:46

小贱钟做好了

架子撘起来了，但是手头只有2个舵机，没办法看到全貌。很是郁闷。分开测试，到是运行的挺流畅。


来个全家福


这个小孔改造的非常棒，和舵机可以实现无螺丝固定，而且配合很完美。


但愿舵机的轴都是这样。


组装很简单


摆拍一个。。那是马克笔，不是白板笔，如果写上了，就再也擦不掉了


少一个舵机，真是挠头


挥舞起来吧


用手持方式写了一个


猜了半天，才看明白，它写的是 00:02，那个零好圆哦

机架结构似乎还是不太合理，还有修改的余地。过几天弄个完美版的，淘宝开个店卖卖20￥一套预定送螺丝哦！


程序奉上，需要时间模块一个，我是用的DS3231，如果是其他时间模块，。H文件需要改一下。字模文件都是程序里写好的路径，如果感觉它的字实在太难看了，可以自己修改。呵呵


#define CALIBRATION      // enable calibration mode
//#define REALTIMECLOCK    // enable real time clock

// When in calibration mode, adjust the following factor until the servos move exactly 90 degrees
#define SERVOFAKTORLEFT 650
#define SERVOFAKTORRIGHT 650

// Zero-position of left and right servo
// When in calibration mode, adjust the NULL-values so that the servo arms are at all times parallel
// either to the X or Y axis
#define SERVOLEFTNULL 2250
#define SERVORIGHTNULL 920

#define SERVOPINLIFT2
#define SERVOPINLEFT3
#define SERVOPINRIGHT 4

// lift positions of lifting servo
#define LIFT0 1080 // on drawing surface
#define LIFT1 925// between numbers
#define LIFT2 725// going towards sweeper

// speed of liftimg arm, higher is slower
#define LIFTSPEED 1500

// length of arms
#define L1 35
#define L2 55.1
#define L3 13.2

// origin points of left and right servo
#define O1X 22
#define O1Y -25
#define O2X 47
#define O2Y -25

#include <Time.h>
#include <Servo.h>
#include <Wire.h>
#include <DS3231.h>   


int servoLift = 1500;

Servo servo1;//
Servo servo2;//
Servo servo3;//

volatile double lastX = 75;
volatile double lastY = 47.5;

int last_min = 0;

void setup()
{

Serial.begin(9600);
Wire.begin();

drawTo(75.2, 47);
lift(0);
servo1.attach(SERVOPINLIFT);//lifting servo
servo2.attach(SERVOPINLEFT);//left servo
servo3.attach(SERVOPINRIGHT);//right servo
delay(1000);

}

void loop()
{

int i = 0;
if (last_min != minute()) {

    if (!servo1.attached()) servo1.attach(SERVOPINLIFT);
    if (!servo2.attached()) servo2.attach(SERVOPINLEFT);
    if (!servo3.attached()) servo3.attach(SERVOPINRIGHT);

    lift(0);

    hour();
    while ((i+1)*10 <= hour())
    {
      i++;
    }

    number(3, 3, 111, 1);
    number(5, 25, i, 0.9);
    number(19, 25, (hour()-i*10), 0.9);
    number(28, 25, 11, 0.9);

    i=0;
    while ((i+1)*10 <= minute())
    {
      i++;
    }
    number(34, 25, i, 0.9);
    number(48, 25, (minute()-i*10), 0.9);
    lift(2);
    drawTo(74.2, 47.5);
    lift(1);
    last_min = minute();

    servo1.detach();
    servo2.detach();
    servo3.detach();
}



}

// Writing numeral with bx by being the bottom left originpoint. Scale 1 equals a 20 mm high font.
// The structure follows this principle: move to first startpoint of the numeral, lift down, draw numeral, lift up
void number(float bx, float by, int num, float scale) {

switch (num) {

case 0:
    drawTo(bx + 12 * scale, by + 6 * scale);
    lift(0);
    bogenGZS(bx + 7 * scale, by + 10 * scale, 10 * scale, -0.8, 6.7, 0.5);
    lift(1);
    break;
case 1:

    drawTo(bx + 3 * scale, by + 15 * scale);
    lift(0);
    drawTo(bx + 10 * scale, by + 20 * scale);
    drawTo(bx + 10 * scale, by + 0 * scale);
    lift(1);
    break;
case 2:
    drawTo(bx + 2 * scale, by + 12 * scale);
    lift(0);
    bogenUZS(bx + 8 * scale, by + 14 * scale, 6 * scale, 3, -0.8, 1);
    drawTo(bx + 1 * scale, by + 0 * scale);
    drawTo(bx + 12 * scale, by + 0 * scale);
    lift(1);
    break;
case 3:
    drawTo(bx + 2 * scale, by + 17 * scale);
    lift(0);
    bogenUZS(bx + 5 * scale, by + 15 * scale, 5 * scale, 3, -2, 1);
    bogenUZS(bx + 5 * scale, by + 5 * scale, 5 * scale, 1.57, -3, 1);
    lift(1);
    break;
case 4:
    drawTo(bx + 10 * scale, by + 0 * scale);
    lift(0);
    drawTo(bx + 10 * scale, by + 20 * scale);
    drawTo(bx + 2 * scale, by + 6 * scale);
    drawTo(bx + 12 * scale, by + 6 * scale);
    lift(1);
    break;
case 5:
    drawTo(bx + 2 * scale, by + 5 * scale);
    lift(0);
    bogenGZS(bx + 5 * scale, by + 6 * scale, 6 * scale, -2.5, 2, 1);
    drawTo(bx + 5 * scale, by + 20 * scale);
    drawTo(bx + 12 * scale, by + 20 * scale);
    lift(1);
    break;
case 6:
    drawTo(bx + 2 * scale, by + 10 * scale);
    lift(0);
    bogenUZS(bx + 7 * scale, by + 6 * scale, 6 * scale, 2, -4.4, 1);
    drawTo(bx + 11 * scale, by + 20 * scale);
    lift(1);
    break;
case 7:
    drawTo(bx + 2 * scale, by + 20 * scale);
    lift(0);
    drawTo(bx + 12 * scale, by + 20 * scale);
    drawTo(bx + 2 * scale, by + 0);
    lift(1);
    break;
case 8:
    drawTo(bx + 5 * scale, by + 10 * scale);
    lift(0);
    bogenUZS(bx + 5 * scale, by + 15 * scale, 5 * scale, 4.7, -1.6, 1);
    bogenGZS(bx + 5 * scale, by + 5 * scale, 5 * scale, -4.7, 2, 1);
    lift(1);
    break;

case 9:
    drawTo(bx + 9 * scale, by + 11 * scale);
    lift(0);
    bogenUZS(bx + 7 * scale, by + 15 * scale, 5 * scale, 4, -0.5, 1);
    drawTo(bx + 5 * scale, by + 0);
    lift(1);
    break;

case 111:

    lift(0);
    drawTo(70, 46);
    drawTo(65, 43);

    drawTo(65, 49);
    drawTo(5, 49);
    drawTo(5, 45);
    drawTo(65, 45);
    drawTo(65, 40);

    drawTo(5, 40);
    drawTo(5, 35);
    drawTo(65, 35);
    drawTo(65, 30);

    drawTo(5, 30);
    drawTo(5, 25);
    drawTo(65, 25);
    drawTo(65, 20);

    drawTo(5, 20);
    drawTo(60, 44);

    drawTo(75.2, 47);
    lift(2);

    break;

case 11:
    drawTo(bx + 5 * scale, by + 15 * scale);
    lift(0);
    bogenGZS(bx + 5 * scale, by + 15 * scale, 0.1 * scale, 1, -1, 1);
    lift(1);
    drawTo(bx + 5 * scale, by + 5 * scale);
    lift(0);
    bogenGZS(bx + 5 * scale, by + 5 * scale, 0.1 * scale, 1, -1, 1);
    lift(1);
    break;

}
}



void lift(char lift) {


switch (lift) {
    // room to optimize!


case 0: //850

      if (servoLift >= LIFT0) {
      while (servoLift >= LIFT0)
      {
      servoLift--;
      servo1.writeMicroseconds(servoLift);                               
      delayMicroseconds(LIFTSPEED);
      }
    }
    else {
      while (servoLift <= LIFT0) {
      servoLift++;
      servo1.writeMicroseconds(servoLift);
      delayMicroseconds(LIFTSPEED);

      }

    }

    break;

case 1: //150

    if (servoLift >= LIFT1) {
      while (servoLift >= LIFT1) {
      servoLift--;
      servo1.writeMicroseconds(servoLift);
      delayMicroseconds(LIFTSPEED);

      }
    }
    else {
      while (servoLift <= LIFT1) {
      servoLift++;
      servo1.writeMicroseconds(servoLift);
      delayMicroseconds(LIFTSPEED);
      }

    }

    break;

case 2:

    if (servoLift >= LIFT2) {
      while (servoLift >= LIFT2) {
      servoLift--;
      servo1.writeMicroseconds(servoLift);
      delayMicroseconds(LIFTSPEED);
      }
    }
    else {
      while (servoLift <= LIFT2) {
      servoLift++;
      servo1.writeMicroseconds(servoLift);                               
      delayMicroseconds(LIFTSPEED);
      }
    }
    break;
}
}


void bogenUZS(float bx, float by, float radius, int start, int ende, float sqee) {
float inkr = -0.05;
float count = 0;

do {
    drawTo(sqee * radius * cos(start + count) + bx,
    radius * sin(start + count) + by);
    count += inkr;
}
while ((start + count) > ende);

}

void bogenGZS(float bx, float by, float radius, int start, int ende, float sqee) {
float inkr = 0.05;
float count = 0;

do {
    drawTo(sqee * radius * cos(start + count) + bx,
    radius * sin(start + count) + by);
    count += inkr;
}
while ((start + count) <= ende);
}


void drawTo(double pX, double pY) {
double dx, dy, c;
int i;

// dx dy of new point
dx = pX - lastX;
dy = pY - lastY;
//path lenght in mm, times 4 equals 4 steps per mm
c = floor(4 * sqrt(dx * dx + dy * dy));

if (c < 1) c = 1;

for (i = 0; i <= c; i++) {
    // draw line point by point
    set_XY(lastX + (i * dx / c), lastY + (i * dy / c));

}

lastX = pX;
lastY = pY;
}

double return_angle(double a, double b, double c) {
// cosine rule for angle between c and a
return acos((a * a + c * c - b * b) / (2 * a * c));
}

void set_XY(double Tx, double Ty)
{
delay(1);
double dx, dy, c, a1, a2, Hx, Hy;

// calculate triangle between pen, servoLeft and arm joint
// cartesian dx/dy
dx = Tx - O1X;
dy = Ty - O1Y;

// polar lemgth (c) and angle (a1)
c = sqrt(dx * dx + dy * dy); //
a1 = atan2(dy, dx); //
a2 = return_angle(L1, L2, c);

servo2.writeMicroseconds(floor(((a2 + a1 - M_PI) * SERVOFAKTORLEFT) + SERVOLEFTNULL));

// calculate joinr arm point for triangle of the right servo arm
a2 = return_angle(L2, L1, c);
Hx = Tx + L3 * cos((a1 - a2 + 0.621) + M_PI); //36,5°
Hy = Ty + L3 * sin((a1 - a2 + 0.621) + M_PI);

// calculate triangle between pen joint, servoRight and arm joint
dx = Hx - O2X;
dy = Hy - O2Y;

c = sqrt(dx * dx + dy * dy);
a1 = atan2(dy, dx);
a2 = return_angle(L1, (L2 - L3), c);

servo3.writeMicroseconds(floor(((a1 - a2) * SERVOFAKTORRIGHT) + SERVORIGHTNULL));

}

mxhhaixin 发表于 2014-5-15 09:17:01

先提前预订一套。
楼主淘宝店地址是什么。

mxhhaixin 发表于 2014-5-15 09:18:27

这个有没有其他颜色的。感觉红色暗了点。弄个鲜明活泼的颜色呗。

mxhhaixin 发表于 2014-5-15 09:27:33

不知道把字体换成数码管显示的那种，写出来会不会更好看些。楼主试验下呗。
还有，能不能做个底座，把小贱钟和Arduino固定在一起。

咯小3虽 发表于 2014-5-15 14:11:16

{:soso_e179:}

mxhhaixin 发表于 2014-5-15 14:13:23

要是卖成品，就集成Mini。卖散件的话，就在底座上钻四个能装UNO的孔。毕竟大家还是用UNO的多。

mxhhaixin 发表于 2014-5-15 17:24:37

mxhhaixin 发表于 2014-5-15 14:13 static/image/common/back.gif
要是卖成品，就集成Mini。卖散件的话，就在底座上钻四个能装UNO的孔。毕竟大家还是用UNO的多。

搞精致点，做成工艺品，就有人愿意花钱了。

for 发表于 2014-5-15 18:51:44

能不能脱离电脑工作？

沧海笑1122 发表于 2014-5-16 14:31:43

激光切割吗？支持！预订！。。。对了，怎么预订啊？

『超人不会飞』 发表于 2014-5-26 11:04:05

求上架日期

shihaipeng04 发表于 2014-6-5 00:57:17

『超人不会飞』 发表于 2014-5-26 11:04 static/image/common/back.gif
求上架日期

【新提醒】plotclock小贱钟套件完工啦 - Powered by Discuz!
http://www.geek-workshop.com/thread-10014-1-1.html

刚刚上线

那一小撮人 发表于 2014-7-24 10:06:49

您好问一下。想按自己轨迹写的话用改那些参数，数据。那些事不用改的？

shihaipeng04 发表于 2014-7-24 10:21:01

那一小撮人 发表于 2014-7-24 10:06 static/image/common/back.gif
您好问一下。想按自己轨迹写的话用改那些参数，数据。那些事不用改的？

程序里有个 drawto函数 还有个 lift抬臂函数 ，就用着个函数控制就能随便画了。比如做个小绘图仪啥的。呵呵

那一小撮人 发表于 2014-7-24 11:08:23

shihaipeng04 发表于 2014-7-24 10:21 static/image/common/back.gif
程序里有个 drawto函数 还有个 lift抬臂函数 ，就用着个函数控制就能随便画了。比如做个小绘图仪啥的。呵 ...

恩谢谢， 你知道有什么类似可以建立坐标纸的软件吗

那一小撮人 发表于 2014-7-25 20:08:03

问一下 bogenUZS函数中的start，ende，sqee代表什么
页: [1] 2
查看完整版本: 小贱钟做好了