ARDUINO+BMP085 lcd显示气压与温度
本帖最后由 504835618 于 2014-8-29 21:16 编辑/*感谢本坛弘毅的代码http://www.geek-workshop.com/thread-1956-1-1.html
我在原来代码基础上加上了u8glibv库，加上LCD液晶作为显示，效果还是很好
BMP模块接线UNO板接A4，A5;其他的接SCL,SDALCD为ST7576驱动-12864液晶屏
从BMP085传感器读取温度与气压数据。
通过Serial.print命令以9600波特率发送至串口监视器。
*/
#include <U8glib.h>
#include <Wire.h>
#define BMP085_ADDRESS 0x77// BMP085的I2C地址
U8GLIB_64128N u8g(13, 11, 10, 9, 8);// SPI Com: SCK = 13, MOSI = 11, CS = 10, A0 = 9, RST = 8
const unsigned char OSS = 0;// 采样设置
// 校准值
int ac1;
int ac2;
int ac3;
unsigned int ac4;
unsigned int ac5;
unsigned int ac6;
int b1;
int b2;
int mb;
int mc;
int md;
// b5用于计算bmp085GetTemperature(...)，它也同时用于bmp085GetPressure(...)
// 所以Temperature(...)必须在Pressure(...)之前声明
long b5;
short temperature;
long pressure;
void setup()
{
Serial.begin(9600);
Wire.begin();
bmp085Calibration();
}
void loop()
{
temperature = bmp085GetTemperature(bmp085ReadUT());
pressure = bmp085GetPressure(bmp085ReadUP());
Serial.print("Temperature: ");
//Serial.println(temperature, DEC);
Serial.println(temperature*0.1);
//Serial.println(" *0.1 deg C");
Serial.print("Pressure: ");
Serial.print(pressure, DEC);
Serial.println(" Pa");
Serial.println();
//delay(1000);
//--------------------
u8g.firstPage();
do {
draw();
}
while( u8g.nextPage() );
delay(1000);
}
//---------图表和图形的处理------------------
void draw(void)
{
u8g.setRot180();//屏幕旋转x度
delay(10);
u8g.setFont(u8g_font_osb26);//字体设置
u8g.setPrintPos(15, 48);
u8g.print(temperature*0.1,2)
u8g.setFont(u8g_font_osb21);
u8g.setPrintPos(110, 48);
u8g.print("C");
u8g.setFont(u8g_font_osb21);
u8g.setPrintPos(100, 45);
u8g.print(char(176));
u8g.setFont(u8g_font_8x13B);
u8g.setPrintPos(30, 15);//X,Y
u8g.print("bmp085.Temp");
u8g.setFont(u8g_font_8x13B);
u8g.setPrintPos(18, 62);
u8g.print(pressure);
u8g.setPrintPos(110, 62);
u8g.print("Pa");
delay(5);
}
//------------------------------
// 存储所有的BMP085的校准值到全局变量
// 校准值用来计算温度与气压
// 这个函数应该放在程序的开头
void bmp085Calibration()
{
ac1 = bmp085ReadInt(0xAA);
ac2 = bmp085ReadInt(0xAC);
ac3 = bmp085ReadInt(0xAE);
ac4 = bmp085ReadInt(0xB0);
ac5 = bmp085ReadInt(0xB2);
ac6 = bmp085ReadInt(0xB4);
b1 = bmp085ReadInt(0xB6);
b2 = bmp085ReadInt(0xB8);
mb = bmp085ReadInt(0xBA);
mc = bmp085ReadInt(0xBC);
md = bmp085ReadInt(0xBE);
}
// 计算温度赋值给变量ut
// 返回值的精度在0.1摄氏度
short bmp085GetTemperature(unsigned int ut)
{
long x1, x2;
x1 = (((long)ut - (long)ac6)*(long)ac5) >> 15;
x2 = ((long)mc << 11)/(x1 + md);
b5 = x1 + x2;
return ((b5 + 8)>>4);
}
// 计算压力
// 校准值必须是已知的
// B5在bmp085GetTemperature（...）需要使用，所以必须先调用。
// 返回值以Pa为单位
long bmp085GetPressure(unsigned long up)
{
long x1, x2, x3, b3, b6, p;
unsigned long b4, b7;
b6 = b5 - 4000;
// 计算B3
x1 = (b2 * (b6 * b6)>>12)>>11;
x2 = (ac2 * b6)>>11;
x3 = x1 + x2;
b3 = (((((long)ac1)*4 + x3)<<OSS) + 2)>>2;
// 计算B4
x1 = (ac3 * b6)>>13;
x2 = (b1 * ((b6 * b6)>>12))>>16;
x3 = ((x1 + x2) + 2)>>2;
b4 = (ac4 * (unsigned long)(x3 + 32768))>>15;
b7 = ((unsigned long)(up - b3) * (50000>>OSS));
if (b7 < 0x80000000)
p = (b7<<1)/b4;
else
p = (b7/b4)<<1;
x1 = (p>>8) * (p>>8);
x1 = (x1 * 3038)>>16;
x2 = (-7357 * p)>>16;
p += (x1 + x2 + 3791)>>4;
return p;
}
// 在BMP085的'address'中读取一个字节
char bmp085Read(unsigned char address)
{
unsigned char data;
Wire.beginTransmission(BMP085_ADDRESS);
Wire.write(address);
Wire.endTransmission();
Wire.requestFrom(BMP085_ADDRESS, 1);
while(!Wire.available());
return Wire.read();
}
// 从BMP085读取两个字节
// 第一个字节是从'address'
// 第二个字节是从'address'+1
int bmp085ReadInt(unsigned char address)
{
unsigned char msb, lsb;
Wire.beginTransmission(BMP085_ADDRESS);
Wire.write(address);
Wire.endTransmission();
Wire.requestFrom(BMP085_ADDRESS, 2);
while(Wire.available()<2);
msb = Wire.read();
lsb = Wire.read();
return (int) msb<<8 | lsb;
}
// 读取未补偿的温度值
unsigned int bmp085ReadUT()
{
unsigned int ut;
// 在寄存器0xF4写入0x2E
// 这个用来请求进行温度读取
Wire.beginTransmission(BMP085_ADDRESS);
Wire.write(0xF4);
Wire.write(0x2E);
Wire.endTransmission();
// 至少等待4.5ms
delay(5);
// 从寄存器0xF6与0xF7读取两个字节
ut = bmp085ReadInt(0xF6);
return ut;
}
// 读取未补偿的压力值
unsigned long bmp085ReadUP()
{
unsigned char msb, lsb, xlsb;
unsigned long up = 0;
// 写入0x34+(OSS<<6)到寄存器0xF4
// 请求气压数据读取
Wire.beginTransmission(BMP085_ADDRESS);
Wire.write(0xF4);
Wire.write(0x34 + (OSS<<6));
Wire.endTransmission();
// 等待转换，延迟时间依赖于OSS
delay(2 + (3<<OSS));
// 读取寄存器0xF6 (MSB), 0xF7 (LSB), and 0xF8 (XLSB)
Wire.beginTransmission(BMP085_ADDRESS);
Wire.write(0xF6);
Wire.endTransmission();
Wire.requestFrom(BMP085_ADDRESS, 3);
// 等待数据变为可用
while(Wire.available() < 3);
msb = Wire.read();
lsb = Wire.read();
xlsb = Wire.read();
up = (((unsigned long) msb << 16) | ((unsigned long) lsb << 8) | (unsigned long) xlsb) >> (8-OSS);
return up;
}
http://bbs.yleee.com.cn/data/attachment/forum/201408/27/205539mog4ldxw4pbo2ozl.jpg.thumb.jpg
http://bbs.yleee.com.cn/data/attachment/forum/201408/27/213850cf86co81crcjr99b.jpg.thumb.jpg
第二图应该是百帕(HPa) 林定祥 发表于 2014-8-28 16:29 static/image/common/back.gif
第二图应该是百帕(HPa)
谢谢，对大气压不懂，所以。 我也是玩了这个才去学的，了解了气压几个单位，气压变化的因数，气压和潮汐关系等。 请问高度转换的代码？？
页:
[1]