HMC5883L转换方向角与简易校准方法

do335maomao

研究了一晚上稍微有点成果分享下

HMC5883L使用i2c接口，接线很容易

以Arduino Uno为例：
SDA to A4
SCL to A5
Vcc to 3.3V
GND to GND

基本原理很简单：
方向角其实就是X轴和Y轴读数的反正切
而校准其实就是要排除环境中的磁场对地磁场的干扰
另外别忘了当地的磁偏角

如下代码没有使用专门的传感器库
上电后先进行20秒校准，请把传感器任意乱转，各个方向都要转到
然后就会显示校准值，然后持续显示初始值和方向角
不知道怎么在ide里面用中文写注释，所以就保留英文了

个人测试下来和手机上的指南针相差不超过5度，更精细的校准待研究

刚刚接触Arduino，望高手指教

1. 
   
2. 
   
3. #include <Wire.h> //I2C Arduino Library
   
4. 
   
5. #define address 0x1E //001 1110b(0x3C>>1), I2C 7bit address of HMC5883
   
6. #define MagnetcDeclination 4.43 //Shanghai
   
7. #define CalThreshold 0
   
8. 
   
9. int offsetX,offsetY,offsetZ;
   
10. 
    
11. void setup()
    
12. {
    
13.   //Initialize Serial and I2C communications
    
14.   Serial.begin(9600);
    
15.   Wire.begin();
    
16. 
    
17.   //Put the HMC5883 IC into the correct operating mode
    
18.   Wire.beginTransmission(address); //open communication with HMC5883r
    
19.   Wire.write(0x00); //select configuration register A
    
20.   Wire.write(0x70); //0111 0000b configuration
    
21.   Wire.endTransmission();
    
22.   
    
23.   Wire.beginTransmission(address);
    
24.   Wire.write(0x02); //select mode register
    
25.   Wire.write(0x00); //set continuous measurement mode:0x00,single-measurement mode:0x01
    
26.   Wire.endTransmission();
    
27.   
    
28.   calibrateMag();
    
29. }
    
30. void loop()
    
31. {
    
32.   int x,y,z; //triple axis data
    
33.   getRawData(&x,&y,&z);
    
34.   
    
35.   //Print out values of each axis
    
36.   Serial.print("x: ");
    
37.   Serial.print(x);
    
38.   Serial.print("  y: ");
    
39.   Serial.print(y);
    
40.   Serial.print("  z: ");
    
41.   Serial.print(z);
    
42.   Serial.print(" angle(x,y): ");
    
43.   Serial.println(calculateHeading(&x,&y,&z));
    
44. 
    
45.   delay(250);
    
46. }
    
47. 
    
48. void getRawData(int* x ,int* y,int* z)
    
49. {
    
50.   //Tell the HMC5883L where to begin reading data
    
51.   Wire.beginTransmission(address);
    
52.   Wire.write(0x03); //select register 3, X MSB register
    
53.   Wire.endTransmission();
    
54.   //Read data from each axis, 2 registers per axis
    
55.   Wire.requestFrom(address, 6);
    
56.   if(6<=Wire.available()){
    
57.     *x = Wire.read()<<8; //X msb
    
58.     *x |= Wire.read(); //X lsb
    
59.     *z = Wire.read()<<8; //Z msb
    
60.     *z |= Wire.read(); //Z lsb
    
61.     *y = Wire.read()<<8; //Y msb
    
62.     *y |= Wire.read(); //Y lsb
    
63.   }
    
64. }
    
65. 
    
66. int calculateHeading(int* x ,int* y,int* z)
    
67. {
    
68.   float headingRadians = atan2((double)((*y)-offsetY),(double)((*x)-offsetX));
    
69.   // Correct for when signs are reversed.
    
70.   if(headingRadians < 0)
    
71.     headingRadians += 2*PI;
    
72.    
    
73.   int headingDegrees = headingRadians * 180/M_PI;
    
74.   headingDegrees += MagnetcDeclination; //the magnetc-declination angle
    
75.   
    
76.   // Check for wrap due to addition of declination.
    
77.   if(headingDegrees > 360)
    
78.     headingDegrees -= 360;
    
79.   
    
80.   return headingDegrees;
    
81. }
    
82. 
    
83. void calibrateMag()
    
84. {
    
85.   int x,y,z; //triple axis data
    
86.   int xMax, xMin, yMax, yMin, zMax, zMin;
    
87.   //initialize the variables
    
88.   getRawData(&x,&y,&z);  
    
89.   xMax=xMin=x;
    
90.   yMax=yMin=y;
    
91.   zMax=zMin=z;
    
92.   offsetX = offsetY = offsetZ = 0;
    
93.   
    
94.   Serial.println("Starting Calibration......");
    
95.   Serial.println("Please turn your device around in 20 seconds");
    
96.   
    
97.   for(int i=0;i<200;i++)
    
98.   {
    
99.     getRawData(&x,&y,&z);
    
100.     //get Max and Min
     
101.     // this routine will capture the max and min values of the mag X, Y, and Z data while the
     
102.     // compass is being rotated 360 degrees through the level plane and the upright plane.
     
103.     // i.e. horizontal and vertical circles.
     
104.     // This function should be invoked while making continuous measurements on the magnetometers
     
105.     if (x > xMax)
     
106.       xMax = x;
     
107.     if (x < xMin )
     
108.       xMin = x;
     
109.     if(y > yMax )
     
110.       yMax = y;
     
111.     if(y < yMin )
     
112.       yMin = y;
     
113.     if(z > zMax )
     
114.       zMax = z;
     
115.     if(z < zMin )
     
116.       zMin = z;
     
117.       
     
118.     delay(100);
     
119.    
     
120.     if(i%10 == 0)
     
121.     {
     
122.       Serial.print(xMax);
     
123.       Serial.print(" ");
     
124.       Serial.println(xMin);
     
125.     }
     
126.   }
     
127.   //compute offsets
     
128.   if(abs(xMax - xMin) > CalThreshold )
     
129.     offsetX = (xMax + xMin)/2;
     
130.   if(abs(yMax - yMin) > CalThreshold )
     
131.     offsetY = (yMax + yMin)/2;
     
132.   if(abs(zMax - zMin) > CalThreshold )
     
133.     offsetZ = (zMax +zMin)/2;
     
134.    
     
135.   Serial.print("offsetX:");
     
136.   Serial.print("");
     
137.   Serial.print(offsetX);
     
138.   Serial.print(" offsetY:");
     
139.   Serial.print("");
     
140.   Serial.print(offsetY);
     
141.   Serial.print(" offsetZ:");
     
142.   Serial.print("");
     
143.   Serial.println(offsetZ);
     
144.   
     
145.   delay(5000);  
     
146. }
     
147. 
     
148. 
     

复制代码

把冗长的数据手册读完了，有人想看的话，可以把自测试模式，空闲模式等的使用方法也写一下

参考资料：
https://www.sparkfun.com/tutorials/301

hardstudy12345

正在研究这个，谢谢楼主分享！

kevinfrankchen

我用的GY86模块，电子罗盘也是HMC5883L，一直显示I2C通讯失败，但是MPU6050这些I2C都没问题，楼主能点拨一下吗？谢谢

do335maomao

kevinfrankchen 发表于 2015-2-27 14:48
我用的GY86模块，电子罗盘也是HMC5883L，一直显示I2C通讯失败，但是MPU6050这些I2C都没问题，楼主能点拨一下 ...

gy86上的hmc5883是连在mpu6050的辅助i2c口上的，需要设置mpu6050才能使用罗盘

kevinfrankchen

do335maomao 发表于 2015-2-28 14:59
gy86上的hmc5883是连在mpu6050的辅助i2c口上的，需要设置mpu6050才能使用罗盘

你好，那你有相关的历程吗？我还以为那个模块坏了，谢谢

do335maomao

kevinfrankchen 发表于 2015-2-28 15:40
你好，那你有相关的历程吗？我还以为那个模块坏了，谢谢

这个我具体也只是看过数据手册，建议你也看一下

frankpian

楼主你好，我看到你的calibrateMag()部分代码的时候，看到只打印出xMax和xMin值，请问校准只需要X轴获取最大和最小即可么？

小白不懂，万分感谢

天天向上/tp

请问M_PI是一个什么数？？我一直没找到

Dreamer-Men

LZ竟然没用HMC5883L库！