BMP085测气压不准是什么原因？

328522073

用的是论坛里BMP085一样的代码，估计论坛里面的也是这个代码将注释翻译过来的吧
可是我测的气压不准，不知道什么原因。
测出来的都是97240Pa这样，我测的是大气压啊..不可能这么低，大气压正常的日变幅最高也就600pa左右，一个标准大气压是101000Pa吧，测出来的结果绝对不合理呀！遇到过这问题的能帮忙解决一下么？是不是这传感器是坏的...

符代码：

1. #include <Wire.h>
   
2. 
   
3. #define BMP085_ADDRESS 0x77  // I2C address of BMP085
   
4. 
   
5. const unsigned char OSS = 0;  // Oversampling Setting
   
6. 
   
7. // Calibration values
   
8. int ac1;
   
9. int ac2;
   
10. int ac3;
    
11. unsigned int ac4;
    
12. unsigned int ac5;
    
13. unsigned int ac6;
    
14. int b1;
    
15. int b2;
    
16. int mb;
    
17. int mc;
    
18. int md;
    
19. 
    
20. // b5 is calculated in bmp085GetTemperature(...), this variable is also used in bmp085GetPressure(...)
    
21. // so ...Temperature(...) must be called before ...Pressure(...).
    
22. long b5;
    
23. 
    
24. short temperature;
    
25. long pressure;
    
26. 
    
27. void setup()
    
28. {
    
29.   Serial.begin(9600);
    
30.   Wire.begin();
    
31.   bmp085Calibration();
    
32. }
    
33. 
    
34. void loop()
    
35. {
    
36.   temperature = bmp085GetTemperature(bmp085ReadUT());
    
37.   pressure = bmp085GetPressure(bmp085ReadUP());
    
38.   Serial.print("Temperature: ");
    
39.   Serial.print(temperature, DEC);
    
40.   Serial.println(" *0.1 deg C");
    
41.   Serial.print("Pressure: ");
    
42.   Serial.print(pressure, DEC);
    
43.   Serial.println(" Pa");
    
44.   Serial.println();
    
45.   delay(1000);
    
46. }
    
47. 
    
48. // Stores all of the bmp085's calibration values into global variables
    
49. // Calibration values are required to calculate temp and pressure
    
50. // This function should be called at the beginning of the program
    
51. void bmp085Calibration()
    
52. {
    
53.   ac1 = bmp085ReadInt(0xAA);
    
54.   ac2 = bmp085ReadInt(0xAC);
    
55.   ac3 = bmp085ReadInt(0xAE);
    
56.   ac4 = bmp085ReadInt(0xB0);
    
57.   ac5 = bmp085ReadInt(0xB2);
    
58.   ac6 = bmp085ReadInt(0xB4);
    
59.   b1 = bmp085ReadInt(0xB6);
    
60.   b2 = bmp085ReadInt(0xB8);
    
61.   mb = bmp085ReadInt(0xBA);
    
62.   mc = bmp085ReadInt(0xBC);
    
63.   md = bmp085ReadInt(0xBE);
    
64. }
    
65. 
    
66. // Calculate temperature given ut.
    
67. // Value returned will be in units of 0.1 deg C
    
68. short bmp085GetTemperature(unsigned int ut)
    
69. {
    
70.   long x1, x2;
    
71.   
    
72.   x1 = (((long)ut - (long)ac6)*(long)ac5) >> 15;
    
73.   x2 = ((long)mc << 11)/(x1 + md);
    
74.   b5 = x1 + x2;
    
75. 
    
76.   return ((b5 + 8)>>4);  
    
77. }
    
78. 
    
79. // Calculate pressure given up
    
80. // calibration values must be known
    
81. // b5 is also required so bmp085GetTemperature(...) must be called first.
    
82. // Value returned will be pressure in units of Pa.
    
83. long bmp085GetPressure(unsigned long up)
    
84. {
    
85.   long x1, x2, x3, b3, b6, p;
    
86.   unsigned long b4, b7;
    
87.   
    
88.   b6 = b5 - 4000;
    
89.   // Calculate B3
    
90.   x1 = (b2 * (b6 * b6)>>12)>>11;
    
91.   x2 = (ac2 * b6)>>11;
    
92.   x3 = x1 + x2;
    
93.   b3 = (((((long)ac1)*4 + x3)<<OSS) + 2)>>2;
    
94.   
    
95.   // Calculate B4
    
96.   x1 = (ac3 * b6)>>13;
    
97.   x2 = (b1 * ((b6 * b6)>>12))>>16;
    
98.   x3 = ((x1 + x2) + 2)>>2;
    
99.   b4 = (ac4 * (unsigned long)(x3 + 32768))>>15;
    
100.   
     
101.   b7 = ((unsigned long)(up - b3) * (50000>>OSS));
     
102.   if (b7 < 0x80000000)
     
103.     p = (b7<<1)/b4;
     
104.   else
     
105.     p = (b7/b4)<<1;
     
106.    
     
107.   x1 = (p>>8) * (p>>8);
     
108.   x1 = (x1 * 3038)>>16;
     
109.   x2 = (-7357 * p)>>16;
     
110.   p += (x1 + x2 + 3791)>>4;
     
111.   
     
112.   return p;
     
113. }
     
114. 
     
115. // Read 1 byte from the BMP085 at 'address'
     
116. char bmp085Read(unsigned char address)
     
117. {
     
118.   unsigned char data;
     
119.   
     
120.   Wire.beginTransmission(BMP085_ADDRESS);
     
121.   Wire.write(address);
     
122.   Wire.endTransmission();
     
123.   
     
124.   Wire.requestFrom(BMP085_ADDRESS, 1);
     
125.   while(!Wire.available())
     
126.     ;
     
127.    
     
128.   return Wire.read();
     
129. }
     
130. 
     
131. // Read 2 bytes from the BMP085
     
132. // First byte will be from 'address'
     
133. // Second byte will be from 'address'+1
     
134. int bmp085ReadInt(unsigned char address)
     
135. {
     
136.   unsigned char msb, lsb;
     
137.   
     
138.   Wire.beginTransmission(BMP085_ADDRESS);
     
139.   Wire.write(address);
     
140.   Wire.endTransmission();
     
141.   
     
142.   Wire.requestFrom(BMP085_ADDRESS, 2);
     
143.   while(Wire.available()<2)
     
144.     ;
     
145.   msb = Wire.read();
     
146.   lsb = Wire.read();
     
147.   
     
148.   return (int) msb<<8 | lsb;
     
149. }
     
150. 
     
151. // Read the uncompensated temperature value
     
152. unsigned int bmp085ReadUT()
     
153. {
     
154.   unsigned int ut;
     
155.   
     
156.   // Write 0x2E into Register 0xF4
     
157.   // This requests a temperature reading
     
158.   Wire.beginTransmission(BMP085_ADDRESS);
     
159.   Wire.write(0xF4);
     
160.   Wire.write(0x2E);
     
161.   Wire.endTransmission();
     
162.   
     
163.   // Wait at least 4.5ms
     
164.   delay(5);
     
165.   
     
166.   // Read two bytes from registers 0xF6 and 0xF7
     
167.   ut = bmp085ReadInt(0xF6);
     
168.   return ut;
     
169. }
     
170. 
     
171. // Read the uncompensated pressure value
     
172. unsigned long bmp085ReadUP()
     
173. {
     
174.   unsigned char msb, lsb, xlsb;
     
175.   unsigned long up = 0;
     
176.   
     
177.   // Write 0x34+(OSS<<6) into register 0xF4
     
178.   // Request a pressure reading w/ oversampling setting
     
179.   Wire.beginTransmission(BMP085_ADDRESS);
     
180.   Wire.write(0xF4);
     
181.   Wire.write(0x34 + (OSS<<6));
     
182.   Wire.endTransmission();
     
183.   
     
184.   // Wait for conversion, delay time dependent on OSS
     
185.   delay(2 + (3<<OSS));
     
186.   
     
187.   // Read register 0xF6 (MSB), 0xF7 (LSB), and 0xF8 (XLSB)
     
188.   Wire.beginTransmission(BMP085_ADDRESS);
     
189.   Wire.write(0xF6);
     
190.   Wire.endTransmission();
     
191.   Wire.requestFrom(BMP085_ADDRESS, 3);
     
192.   
     
193.   // Wait for data to become available
     
194.   while(Wire.available() < 3)
     
195.     ;
     
196.   msb = Wire.read();
     
197.   lsb = Wire.read();
     
198.   xlsb = Wire.read();
     
199.   
     
200.   up = (((unsigned long) msb << 16) | ((unsigned long) lsb << 8) | (unsigned long) xlsb) >> (8-OSS);
     
201.   
     
202.   return up;
     
203. }
     

复制代码

328522073

这个结果是准的....我们这海拔高度是321.7米，用压高公式计算一下，这个结果是对的。大气压随高度增加而降低....

林定祥

呵呵,气压预报通常有参考点,如海拔高度和地理位置(环境密度影响).海拔高度确实会对气压造成影响,不少利用相对气压来换算高度的变换,如登山,飞机等.

林定祥

通常海拔0,气压在1000百帕左右(hPa).

飞翔的红猪

970hPa，很正常啊

林定祥

气压和云层和潮汐都有关,有根据气压来进行天晴雨预报的.

学慧放弃

有没有精度高的气压计？？？